Ha az internet nem működik, és nyomon kell követnie, hogy van-e kapcsolat vagy nincs, a legegyszerűbb módja annak, hogy figyelje a WiFi szimbólumot a Windows 10 rendszertálcáján. Ha megszakad az internetkapcsolat, sárga felkiáltójel jelenik meg a WiFi szimbólumon. Webhelyet is pingelhet. Ha nem tudja szemmel tartani a tálcát, és a ping fárasztónak tűnik, Windows 10 rendszeren egy egyszerű szkript segítségével beállíthat hangos internetkapcsolati riasztásokat.
SPOILER FIGYELMEZTETÉS: Görgessen le, és tekintse meg a cikk végén található oktatóvideót.
Internetkapcsolati figyelmeztetések
Ezt a szkriptet eredetileg Superuser Fabby írta, és a VMMF fejlesztette tovább. A szkript megköveteli, hogy töltsön le egy ingyenes segédprogramot GNU segédprogramok Win32-hez. Bontsa ki, és keresse meg a következő mappában a Sleep.exe nevű EXE-t.
UnxUtilsusrlocalwbin
Ez arra szolgál, hogy várakozási időt adjon az ellenőrzések között. Ennek az EXE-nek ugyanabban a mappában kell lennie, ahová a szkriptet menti. Nincs szükséged másra, ezért nyugodtan töröld.
Nyissa meg a Jegyzettömböt, és illessze be a következőket. Mentse el CMD kiterjesztéssel, és futtassa a fájlt. A sound.vbs fájlt a szkript hozza létre, ezért ne aggódjon miatta.
@ECHO OFF
:whileNoInternet
set "host=8.8.8.8"
::check if internet is working
PING -n 1 -w 5000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% neq 0 (
::the internet is not working keep cheking until it does
echo No internet yet %TIME%
GOTO whileNoInternet
)
echo we gained internet
::the internet is working play internet ON song
@echo off
set "file=InternetON_GOGOGO.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
echo Sound.URL = "%file%"
echo Sound.Controls.play
echo do while Sound.currentmedia.duration = 0
echo wscript.sleep 100
echo loop
echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs
@ECHO OFF
:whileInternet
sleep.exe 5s
::check if internet is still working
PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% == 0 (
::the internet is still working keep cheking until it does not
echo We have internet %TIME%
GOTO whileInternet
)
:: detect possible internet glitches (do not trust the first failure)
echo internet glitch detected
sleep.exe 10s
PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% == 0 (
::the internet is still working keep cheking until it does not
echo We have internet %TIME%
GOTO whileInternet
)
:: if it failed twice in a row most likely internet is down
echo we lost internet
::the internet is not working anymore, play internet OFF song
@echo off
set "file=InternetHasFallen.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
echo Sound.URL = "%file%"
echo Sound.Controls.play
echo do while Sound.currentmedia.duration = 0
echo wscript.sleep 100
echo loop
echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs
::start monitoring if it comes back
GOTO whileNoInternet
Csak ennyit kell tennie. Nyitva marad egy parancssori ablak, amely ellenőrzi az internetkapcsolat állapotát. Ha megváltozik, az Off hangot fogja hallani.